Gecko [ www.leshallesdegournay.geraud-market.com ]

Linux worldls-302.fr.planethoster.net 4.18.0-553.8.1.lve.el7h.x86_64 #1 SMP Thu Jul 4 15:19:33 UTC 2024 x86_64
LiteSpeed
Server IP : 10.185.0.203 & Your IP : 216.73.216.32
Domains : Cant Read [ /etc/named.conf ]
User : gerathty

Name	Size	Permission	Date
assert.awk	382 B	-rw-r--r--	2017-06-28 20:16
bits2str.awk	327 B	-rw-r--r--	2017-06-28 20:16
cliff_rand.awk	307 B	-rw-r--r--	2017-06-28 20:16
ctime.awk	233 B	-rw-r--r--	2017-06-28 20:16
ftrans.awk	317 B	-rw-r--r--	2017-06-28 20:16
getopt.awk	2.18 KB	-rw-r--r--	2017-06-28 20:16
gettime.awk	2.43 KB	-rw-r--r--	2017-06-28 20:16
group.awk	1.75 KB	-rw-r--r--	2017-06-28 20:16
join.awk	378 B	-rw-r--r--	2017-06-28 20:16
libintl.awk	238 B	-rw-r--r--	2017-06-28 20:16
noassign.awk	425 B	-rw-r--r--	2017-06-28 20:16
ord.awk	937 B	-rw-r--r--	2017-06-28 20:16
passwd.awk	1.17 KB	-rw-r--r--	2017-06-28 20:16
quicksort.awk	1023 B	-rw-r--r--	2017-06-28 20:16
readable.awk	492 B	-rw-r--r--	2017-06-28 20:16
rewind.awk	404 B	-rw-r--r--	2017-06-28 20:16
round.awk	661 B	-rw-r--r--	2017-06-28 20:16
strtonum.awk	1.43 KB	-rw-r--r--	2017-06-28 20:16
walkarray.awk	214 B	-rw-r--r--	2017-06-28 20:16
zerofile.awk	424 B	-rw-r--r--	2017-06-28 20:16

Rename

# group.awk --- functions for dealing with the group file
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
# May 1993
# Revised October 2000
# Revised December 2010

BEGIN    \
{
    # Change to suit your system
    _gr_awklib = "/usr/libexec/awk/"
}

function _gr_init(    oldfs, oldrs, olddol0, grcat,
                             using_fw, using_fpat, n, a, i)
{
    if (_gr_inited)
        return

oldfs = FS
    oldrs = RS
    olddol0 = $0
    using_fw = (PROCINFO["FS"] == "FIELDWIDTHS")
    using_fpat = (PROCINFO["FS"] == "FPAT")
    FS = ":"
    RS = "\n"

grcat = _gr_awklib "grcat"
    while ((grcat | getline) > 0) {
        if ($1 in _gr_byname)
            _gr_byname[$1] = _gr_byname[$1] "," $4
        else
            _gr_byname[$1] = $0
        if ($3 in _gr_bygid)
            _gr_bygid[$3] = _gr_bygid[$3] "," $4
        else
            _gr_bygid[$3] = $0

n = split($4, a, "[ \t]*,[ \t]*")
        for (i = 1; i <= n; i++)
            if (a[i] in _gr_groupsbyuser)
                _gr_groupsbyuser[a[i]] = \
                    _gr_groupsbyuser[a[i]] " " $1
            else
                _gr_groupsbyuser[a[i]] = $1

_gr_bycount[++_gr_count] = $0
    }
    close(grcat)
    _gr_count = 0
    _gr_inited++
    FS = oldfs
    if (using_fw)
        FIELDWIDTHS = FIELDWIDTHS
    else if (using_fpat)
        FPAT = FPAT
    RS = oldrs
    $0 = olddol0
}
function getgrnam(group)
{
    _gr_init()
    return _gr_byname[group]
}
function getgrgid(gid)
{
    _gr_init()
    return _gr_bygid[gid]
}
function getgruser(user)
{
    _gr_init()
    return _gr_groupsbyuser[user]
}
function getgrent()
{
    _gr_init()
    if (++_gr_count in _gr_bycount)
        return _gr_bycount[_gr_count]
    return ""
}
function endgrent()
{
    _gr_count = 0
}